Thethered bracketing with EOS Utility and Papywizard  

Everything you need to motorize your head
no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

Thethered bracketing with EOS Utility and Papywizard

by sjhenry » Sat Mar 28, 2009 12:41 am

I have written a small script to use the Canon given EOS Utility to do the exposure bracketing. I have tested it with Digital Rebel (300D), Rebel XSI (450D) and 20D. It seems to work fine. I tested in XP SP3 both in laptop and netbook.

The idea behind this is to simulate the key strokes as if you were using the EOS Utility manually by this script. This will allow Papywizard's shoot.py to shoot multiple exposure. The script is for the AutoHotKey software.

NOTE: Don't run the Windows Task Manager window. Sometimes the script goes there instead of the EOS Utility.

NOTE2: If it is not working, make sure the window class name correct in your machine by using the Window Spy given in the AutoHotKey download.

The script is below. Remove the "Code:" part

Old script is deleted. See the below post for the new one.

The needed bracket.ini file is below. Remove the "Code": part.

Old bracket.ini file is deleted. See the below post for the new one.

Jones
Last edited by sjhenry on Fri Apr 03, 2009 4:43 am, edited 1 time in total.

User avatar
Castillonis
Member
 
Posts: 264
Likes: 0 post
Liked in: 0 post
Joined: Thu Mar 06, 2008 8:49 pm
Location: Oakland, Ca
Info

by Castillonis » Sat Mar 28, 2009 1:01 am

Sounds great. I am planning on buying a Merlin / Orion and eventually a netbook

Did you see the DSLRRemotePro's use of Autohotkey to automate focus stacking when you are using a Canon DSLR with the live view function? I don't know if any other DSLR manufacturers provide libraries that allow you to remotely control the focus.

http://www.breezesys.com/DSLRRemotePro/focus_stacking.htm
http://www.breezesys.com/DSLRRemotePro/liveviewfinder.htm

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Sat Mar 28, 2009 2:46 am

Actually the EOS Utility is also allowing you to set the focus in different point only for the live-view enabled EOS digital cameras. The only thing is that the lens should be set in auto focus mode instead of the manual mode. I tried it with XSI and works fine. I don't know how the DSLR Remote implemented. The Canon EOS Utility has 6 different arrows like (<<<, <<, <, >, >>, >>>). Left arrows are for near focus and right arrows are for far focus.

I created this script so that the Papywizard users have a simple way to use the tools they already have.

Jones

User avatar
fma38
Moderator
 
Posts: 5850
Likes: 2 posts
Liked in: 2 posts
Joined: Wed Dec 07, 2005 6:21 pm
Location: Grenoble, France
Info

by fma38 » Sat Mar 28, 2009 7:28 am

Jones, this is really good job! I don't have time to test all this now (and I'm not a windows user ;o) ), but it sounds great.

I suggest we start a dedicated page on the wiki to put all tethered solutions (don't forget to add a version number to all your files, with some sort of simple ChangeLog).
Frédéric

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Tue Mar 31, 2009 1:25 am

Frederic, Thanks for the input. Is there a wiki already exists for the Papywizard or tethered solution? I can add it to it. I'll put the version number and change log as well.

As Castillonis pointed out, I can add the focus stacking feature to this script as well. Let me try that.

Jones

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Tue Mar 31, 2009 1:32 am

One more thing I forgot to mention about running this script in a netbook.

The netbook should be set to resolution 1024X768. First this is needed so that the EOS Utility can be installed. Otherwise the EOS Installer will not install. Since the script uses the position X,Y to locate the Main Window button, when running the script, the screen resolution set to 1024X768 as well. Most current generation netbook has the resolution by default set to 1024X600 only.

Jones

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Fri Apr 03, 2009 4:47 am

The new script EOSBracker.ahk is here. Remove the "Code:" part.

Code: Select all
;========================================================================
; The main idea of the script is to use the Canon given EOS Utility to
; take multiple exposure shots in an automated way. This will allow
; the script to be executed by the Papywizard shoot.py script.
;
; The real thing is done by sending the needed key strokes to EOS Utility
; so that the correct shutter speed is set and the shutter button is pressed.
;
; For the command line use, the first parameter should be CL.
;
; Software needed:
;    AutoHotKey from http://www.autohotkey.com/
;    Canon Camera Driver for your EOS Digital camera
;    EOS Utility that comes with the camera
;
; How to use:
;    0. Install the AutoHotKey
;    1. Copy the content of this script to a file called
;       EOSBracket.ahk
;    2. Place the file in the Papywizard directory
;       (For example C:\Program Files\Papywizard)
;    3. Right click on the script and select the compile option
;       This will create an stand alone executable EOSBracket.exe
;    4. Copy the exposure bracket information and place it in the
;       Papywizard root directory named as bracket.ini
;    5. Change the shoot.py script to execute EOSBracket.exe
;    6. Run the Papywizard
;    7. Run the EOS Utility and go to the Camera window
;       8. Try it in simulation mode (with Shoot=n in bracket.ini)
;    9. Take the real thing!
;
; Commandline Use (no need for bracket.ini):
;    0. The first parameter should be CL
;    1. The parameters are of the same order as in bracket.ini
;       For explanation of the parameter, see the bracket.ini file
;        a. EOSUtilityType
;        b. BracketValue
;        c. BracketType
;        d. BracketNumber
;        e. Shoot
;        f. BulbMode
;        g. BulbBaseExposure
;        h. FocusBracket
;        i. FocusDirection
;        j. FocusStep
;        k. FocusStepCount
;        l. FocusNumber
;
; Papywizard plugin use:
;     The Papywizard plugin named "EOS Utility" will have three different tabs.
;    The Main tab will allow the user to set the following values
;        a. EOSUtilityType
;        b. BracketValue
;        c. BracketType
;        d. BracketNumber
;        e. Shoot
;    The Bulb tab will allow the user to set the following values
;        f. BulbMode
;        g. BulbBaseExposure
;    The Focus tab will allow the user to set the following values
;        h. FocusBracket
;        i. FocusDirection
;        j. FocusStep
;        k. FocusStepCount
;        l. FocusNumber
;
; DISCLAIMER:
;    This script is provided "AS IS". You are responsible for any
; demage using this script.
;
; Author: Jones Henry Subbiah
;
; 0.0    Initial version for exposure bracketing
; 0.1    Added support for the old EOS Utility
; 0.2    Added bulb exposure bracketing
; 0.3    Added command line interface to work wiht plugin architecture
; 0.4    Added focust bracketing
;=========================================================================

; The window class name for the new EOS Utility.
; This value will be overwritten below for the old EOS Utility
ClassName := "WindowsForms10.Window.8.app.0.3553390"

; Initialize all the global variables

; EOS Utility type
eosut := "NEW"

; Exposure bracket value in 1/3 stops
eval := 2.0

; Exposure bracket type
btype := 3

; Number of exposures
bnum := 3

; Simulation mode or real
shoot := "N"

; Bulb mode or not
bm := "N"

; Bulb base exposure
bbe := 1.0

; Focus bracket mode
fm := "N"

; Focus direction
fd := "FAR"

; Focus step
fs := "MEDIUM"

; Focus step count
fsc := 1

; Number of focus stack pictues
fn := 1

; Check to see if it is a command line mode
if ( %0% > 0 and %1% = CL )
{
    ;MsgBox, Command Line parameters
    ;MsgBox, 0: %0% 1: %1% 2: %2% 3: %3% 4: %4% 5: %5% 6:%6% 7:%7% 8:%8% 9:%9% 10:%10% 11:%11% 12:%12% 13:%13%
    eosut = %2%
    eval = %3%
    eval += 0.0
    btyeval = %4%
    bnum = %5%
    shoot = %6%
    bm = %7%
    bbe = %8%
    bbe += 0.0
    fm = %9%
    fd = %10%
    fs = %11%
    fsc = %12%
    fn = %13%
    ;MsgBox,  eosut:%eosut% eval:%eval% btye:%btype% bnum:%bnum% shoot:%shoot% bm:%bm% bbe:%bbe% fm:%fm% fd:%fd% fs:%fs% fsc:%fsc% fn:%fn%

}
; Get the parameters from the .ini file
else
{
    ;MsgBox, INI file parameters
    ; Read the EOSUtilityType parameter
    ; EOS Utility type. Default is NEW.
    IniRead, eosut, bracket.ini, BracketSetting, EOSUtilityType, NEW

    ; Read the bracket value from bracket.ini file
    ; It is of the form (num) (num)/(num)
    ; The default value is 2 stops
    IniRead, bval, bracket.ini, BracketSetting, BracketValue, 2

    ; Assume the whole number is 0.0
    wnum := 0.0

    ; Split the input by space
    StringSplit, we, bval, %A_Space%

    ; Found the space, then parse the number and fraction seperately
    if ( we0 = 2 )
    {
        ; Take care of the number
        wnum := we1 + 0.0

        ; Parse the fraction
        StringSplit, va, we2, /
        num := va1 + 0.0
        den := va2 + 0.0
        eval := num / den
    }
    else
    {
        ; Got only the fraction part. Parse the fraction
        StringSplit, va, bval, /
        if ( va0 = 2 )
        {
            num := va1 + 0.0
            den := va2 + 0.0
            eval := num / den
        }
        else
        {
            ; Got only the number. Parse the number
            wnum := bval + 0.0
        }
    }
    eval += wnum

    ; Read the bracket type from bracket.ini file
    ; The default type is the Camera AEB -,0,+ mode
    IniRead, btype, bracket.ini, BracketSetting, BracketType, 3

    ; Read the bracket number from bracket.ini file
    ; The number of exposures. Default is 3.
    IniRead, bnum, bracket.ini, BracketSetting, BracketNumber, 3

    ; Read the shoot parameter for simulation or real shooting
    ; For simulation mode. Default is N
    IniRead, shoot, bracket.ini, BracketSetting, Shoot, N

    ; Read the BulbMode parameter
    ; Bulb Mode. Default is N
    IniRead, bm, bracket.ini, BracketSetting, BulbMode, N

    ; Read the BulbBaseExposure parameter
    ; Bulb base exposure. Default is 1 second.
    IniRead, bbe, bracket.ini, BracketSetting, BulbBaseExposure, 1.0
    bbe += 0.0

    ; Read the FocusBracket parameter
    ; Focus bracket enabled or not. Default is N.
    IniRead, fb, bracket.ini, BracketSetting, FocusBracket, N

    ; Read the FocusDirection parameter
    ; Focus direction near or far. Default is FAR.
    IniRead, fd, bracket.ini, BracketSetting, FocusDirection, FAR

    ; Read the FocusSteps parameter
    ; Focus steps - small(< or >), medium (<< or >>), large(<<< or >>>). Default is MEDIUM.
    IniRead, fs, bracket.ini, BracketSetting, FocusSteps, MEDIUM

    ; Read the FocusStepCount parameter
    ; Number of focus steps. Default is 1.
    IniRead, fsc, bracket.ini, BracketSetting, FocusStepCount, 1
    fsc += 0

    ; Read the FocusNumber parameter
    ; Number of images for focus bracketing. Default is 1.
    IniRead, fn, bracket.ini, BracketSetting, FocusNumber, 1
    fn += 0

    ;MsgBox,  eosut:%eosut% eval:%eval% btye:%btype% bnum:%bnum% shoot:%shoot% bm:%bm% bbe:%bbe% fm:%fm% fd:%fd% fs:%fs% fsc:%fsc% fn:%fn%

} ; End of getting parameters

; Make upper case
StringUpper, shoot, shoot
StringUpper, bm, bm
StringUpper, eosut, eosut
StringUpper, fb, fb
StringUpper, fd, fd
StringUpper, fs, fs

;MsgBox,  eosut:%eosut% eval:%eval% btye:%btype% bnum:%bnum% shoot:%shoot% bm:%bm% bbe:%bbe% fm:%fm% fd:%fd% fs:%fs% fsc:%fsc% fn:%fn%

; If the old EOS Utility is used, set the window class correctly
; and make sure the bulb mode is truned off
IfEqual, eosut, OLD
{
    ClassName := "#32770"
    bm := "N"
    fm := "N"
}

; Find out the # of left/right arrow key press for each bracket
acount := 0
iexp := 1.0 / 3.0

while ( 1 )
{
    if ( eval < iexp )
        break
    if ( eval >= iexp )
        acount += 1
        iexp += 1.0 / 3.0
}

GoTo, start

; This function press the shutter button. It handles
; the bulb mode as well.
press_shutter()
{
    ; Global values needed
    global shoot, bm, bbe

    ; If it Bulb mode, send the first shutter (space bar)
    ; to open the shutter
    IfEqual, bm, Y
    {
        IfEqual, shoot, Y
        {
            Send {Space}
        }
        l_bbe := bbe + 1.0
        l_bbe *= 1000
        Sleep, %l_bbe%
    }

    ; For the regular mode or to close the shutter
    ; of Bulb mode, send the shutter again
    IfEqual, shoot, Y
    {
        Send {Space}
    }

    ; Wait for a second
    Sleep, 1000
}

; This function does all the over exposures.
do_overexposure(oecnt)
{
    ; Global values needed
    global acount, bbe, bm

    ; Save the Bulb base exposure for now
    old_bbe := bbe

    ; Shoot the over exposure
    Loop, %oecnt%
    {
        ; In the Bulb mode, calculate the shutter speed
        IfEqual, bm, Y
        {
                        bbe *= ( acount / 3.0 ) * 2.0
        }
        ; In the regular mode, press Left key for the shutter speed
        else
        {
            Send {Left %acount%}
            Sleep, 1000
        }

        ; Press the shutter
        press_shutter()
    }

    ; In the regular mode, set the exposure back to normal
    IfNotEqual, bm, Y
    {
        ; Go to normal exposure
        ncnt := oecnt * acount
        Send {Right %ncnt%}
    }

    ; Save back the Bulb base exposure
    bbe := old_bbe
}

; This function does all the under exposures.
do_underexposure(uecnt)
{
    ; Global values needed
    global acount, bbe, bm

    ; Save the Bulb base exposure for now
    old_bbe := bbe

    ; Shoot the under exposure
    Loop, %uecnt%
    {
        ; In the Bulb mode, calculate the shutter speed
        IfEqual, bm, Y
        {
                        bbe /= ( acount / 3.0 ) * 2.0
        }
        ; In the regular mode, press Right key for the shutter speed
        else
        {
            Send {Right %acount%}
            Sleep, 1000
        }

        ; Press the shutter button
        press_shutter()
    }

    ; In the regular mode, set the exposure back to normal
    IfNotEqual, bm, Y
    {
        ;MsgBox, uecnt: %uecnt% acount: %acount%
        ; Go to normal exposure
        ncnt := uecnt * acount
        Send {Left %ncnt%}
    }

    ; Save back the Bulb base exposure
    bbe := old_bbe
}

; This function does all the exposure bracketing
do_exposure_bracketing()
{
    global btype, bnum

    ; Shoot the normal exposure
    press_shutter()

    ; Regular +- bracketing
    if ( btype = 3 )
        ocnt := ( bnum - 1 ) / 2

    ; Over exposure + bracketing
    if ( btype = 2 )
        ocnt := bnum - 1

    ; Shoot the over exposure
    do_overexposure( ocnt )

    ; Regular +- bracketing
    if ( btype = 3 )
        ucnt := ( bnum - 1 ) / 2

    ; Under exposure - bracketing
    if ( btype = 2 )
        ucnt := bnum - 1

    ; Shoot the under exposure
    do_underexposure( ucnt )
}

; This fucntion opens the live window
goto_live_window()
{
    Send +{Tab 5}
    Send {Enter}
}

set_focus_change()
{
    global fd, fs, fsc

    Sleep, 3000
    ;MsgBox, fd: %fd% fs: %fs% fsc: %fsc%
    tcnt := 0

    ; First find the # of tabs needed to go the correct focus button
    IfEqual, fd, NEAR
    {
        ;MsgBox, NEAR
        IfEqual, fs, SMALL
            tcnt := 6
        IfEqual, fs, MEDIUM
            tcnt := 5
        IfEqual, fs, LARGE
            tcnt := 4
    }

    IfEqual, fd, FAR
    {
        ;MsgBox, FAR
        IfEqual, fs, SMALL
            tcnt := 7
        IfEqual, fs, MEDIUM
            tcnt := 8
        IfEqual, fs, LARGE
            tcnt := 9
    }
    ;MsgBox, tcnt: %tcnt%

    ; Set the focus on the correct focus button
    Send {Tab %tcnt%}
    Sleep, 1000
    ;MsgBox, wait1...

    ; Change the focus
    Loop, %fsc%
    {
        Send {Space}
        Sleep, 100
        ;MsgBox, wait2...
    }
    Sleep, 1000

    tcnt++
    ; Go to Close button and press enter
    Send +{Tab %tcnt%}
    Send {Enter}
    Sleep, 1000

    ; If EOS Utility is running, select the screen
    if (WinExist("ahk_class" . ClassName))
    {
            WinActivate
    }

    ; Go to shutter speed box
    Send {Tab 4}
}

start:

; If EOS Utility is running, select the screen
if (WinExist("ahk_class" . ClassName))
{
    WinActivate
}
; If not, just give the error message and done with it
else
{
    MsgBox No EOS Utility window exists.
    return
}

; Wait for a millisecond
sleep 1

; Set the focus to the shutter button
; First find the Main Window... button and tab two times for the new EOS Utility
; Find the Setup button and tab one time for the old EOS Utility
searchString := "Main Window"
IfEqual, eosut, OLD
{
    MouseMove, 220, 380
    searchString := "Setup"
}
else
{
    MouseMove, 200, 600
    searchString := "Main Window"
}

MouseGetPos,,,id2,control2
ControlGetText,tval2,%control2%
ControlFocus, %control2%

; If we found the button, good
IfInString, tval2, %searchString%
{
    goto shutter
}
else
{
    MsgBox Unable to find the %searchString% button for EOS Utility
    return
}

shutter:

; Go to Shutter box
Send {Tab}
IfNotEqual, eosut, OLD
{
    Send {Tab}
}

; In bulb mode, make sure we are at bulb exposure
IfEqual, bm, Y
{
    Send {Down}
}

do_exposure_bracketing()

IfEqual, fm, Y
{
    ;MsgBox, Focus Bracketing... fn: %fn%
    fn--
    ;MsgBox, fn: %fn%
    ; Loop for each focus bracket
    Loop, %fn%
    {
        ;MsgBox, inside loop...
        goto_live_window()
        set_focus_change()
        do_exposure_bracketing()
    }

}

; Wait for a second
Sleep, 1000

; Done with the script
return

The new bracket.ini file is here. Remove the "Code:" part.

Code: Select all
;============================================================
; This bracket.ini file should be placed in the same
; directory where Papywizard is intalled. For example,
; C:\Porgram Files\Papwizard.
;
; Author: Jones Henry Subbiah
;
;============================================================

[BracketSetting]
;============================================================
; EOSUtilityType    This parameter is to specify whether
;            the EOS Utility is the old one used
;            with Digital Rebel, 20D etc
;            or the new one (black screen)
;            old,OLD        Cameras like 300D, 20D
;            new,NEW        Cameras like 450D
;
; NOTE:    If the value is old, the BULB mode will be disabled since
; EOS Utility is not supporting that functionality
;============================================================
EOSUtilityType=new

;============================================================
; BracketValue    This parameter is to specify the exposure
;        bracket value in 1/3 steps. For example,
;        1/3, 1 2/3 and 2 are possible values.
;============================================================
BracketValue=1

;============================================================
; BracketType    This parameter is the type of bracketing.
;        The possible values are
;        1    Over Exposure Bracketing
;            In this mode, the shutter speed
;            will be reduced by the amount of
;            BracketValue. For example, if the
;            BracketValue is 1 and the initial
;            shutter is 1/500, then the next
;            shot will be at 1/250, 1/60 etc
;
;        2    Under Exposure Bracketing
;            In this mode, the shutter speed
;            will be increased by the amount of
;            BracketValue. For example, if the
;            BracketValue is 1 and the initial
;            shutter is 1/500, then the next
;            shot will be at 1/1000, 1/ etc
;
;        3    Regular Bracketing
;            This works just like the in-camera
;            exposure bracketing - like a normal,
;            over and under exposure
;============================================================
BracketType=3

;============================================================
; BracketNumber    This parameter is to specify the number of
;        bracketed shots to be taken
;============================================================
BracketNumber=3

;============================================================
; Shoot        This parameter is to try out the sequence of
;        exposure before taking the shot.
;        y,Y    This will take the actual shot
;        n,N    This will not take the shot
;============================================================
Shoot=n

;============================================================
; BulbMode    This parameter is to know if the exposures
;        will be using the Bulb mode in the camera.
;        In this case, the exposure time will be
;        calculated for other exposures from the
;        base exposure.
;        y,Y    This will enable the bulb mode if
;            EOS Utility supports
;        n,N    This will disable the bulb mode
;
; NOTE: EOS Utility did not support the Bulb mode for 20D
; and for 300D it went to Bulb mode but disabled the shutter
; button.
;============================================================
BulbMode=n

;============================================================
; BulbBaseExposure    This parameter is to specify the
;            base bulb exposure time in seconds.
;============================================================
BulbBaseExposure=4

;============================================================
; FocusBracket        This parameter is to specify whether
;            the Focus Bracketing is done or not.
;            This can be combined with the regular
;            exposure bracketing.
;            Default is N
;            y,Y    Focus Bracketing enabled
;            n,N    Focus Bracketing disabled
;============================================================
FocusBracket=n

;============================================================
; FocusDirection    This parameter is used to change the
;            focus towards camera (near) or away
;            from the camear (far).
;            Default is FAR
;            near,NEAR    Focus is changed towards
;                    the camera (<,<<,<<<)
;            far,FAR        Focus is changed away
;                    from the camera (>,>>,>>>)
;============================================================
FocusDirection=far

;============================================================
; FocusStep        This parameter is used to specify
;            the focus step or the increment in
;            the focus change to be used.
;            Default is MEDIUM
;            small,SMALL    < or > key
;            medium,MEDIUM    << or >> key
;            large,LARGE    <<< or >>> key
;============================================================
FocusStep=medium

;============================================================
; FocusStepCount    This parameter is used to specify
;            how many number of FocusStep (defined
;            in the previous parameter) to be used
;            for each focus interval
;            Default is 1
;============================================================
FocusStepCount=1

;============================================================
; FocusNumber        This parameter is used to specify
;            the number of focus bracketing images
;            for the focus bracketing.
;            Default is 1
;============================================================
FocusNumber=3

Jones

no avatar
AerialVr
Member
 
Posts: 45
Likes: 0 post
Liked in: 0 post
Joined: Thu Jan 15, 2009 5:53 pm
Location: Swansea,Ma
Info

by AerialVr » Thu May 07, 2009 1:00 pm

Hi Jones,

I have been trying to get your script working and im almost there. if i have the "shoot photo" unchecked papywizard will wait will eos utility goes thru the 5 shudder speeds and then continue on to the next position. when i check the "shoot" box the mount goes to the first position, eos utility takes the first in a series of 5 and then the mount continues on to position two. i get a window popping up with the first image and an error message that the script cant find the main window button. i did have some images on the card from a previous shoot could that be it? also am i supposed to check or uncheck a box so that window with the image does not come up. I can't wait to get this working as it will be awesome to have the wide range and choice for number of images for bracketing and have it automatic. I will appreciate any help you can give. Perhaps a screen shot of how the eos utility should be set would be a good thing for all.

Thanks
Chris Blake

no avatar
AerialVr
Member
 
Posts: 45
Likes: 0 post
Liked in: 0 post
Joined: Thu Jan 15, 2009 5:53 pm
Location: Swansea,Ma
Info

by AerialVr » Thu May 07, 2009 6:13 pm

I also forgot to ask do i need the shoot.py script to use this with the latest dev version im guessing no but this is all a little over my head anyway

Thanks

User avatar
fma38
Moderator
 
Posts: 5850
Likes: 2 posts
Liked in: 2 posts
Joined: Wed Dec 07, 2005 6:21 pm
Location: Grenoble, France
Info

by fma38 » Thu May 07, 2009 7:14 pm

No, the shoot.py script has been replaced by the plugins.
Frédéric

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Fri May 08, 2009 2:40 am

Hi Chris,

As Frederic mentioned, there is no need to have shoot.py. The plugin replaces that. I did a small test 2 images mosaic with each image exposed 3 times with 1 stop apart. It worked fine when the "Shoot" box is checked and unchecked. I am guessing that you have a connection to your EOS camera from the mount. When you use the plugin, the connection to the camera should be coming only from the laptop/desktop using USB cable.

I am going to write a small user guide here as well.

1. Connect the Merlin to the computer via wired USB or Bluetooth.
2. Turn on the mount.
3. Place EOS DSLR on the L bracket and attach to the mount.
4. Connect the EOS DSLR camera to computer via USB cable.
5. Turn on the camera.
6. Make sure the shutter cable from the mount is NOT connected to the EOS DSLR.
7. Make sure you have the EOSBracket.exe is in the Papywizard directory (see attached picture: eupg_00.png)
8. Open EOS Utility program (see attached picture: eupg_01.png)
9. Choose "Camera Settings/Remote Shooting" (see attached picture: eupg_01.png)
10. Now the EOS DSLR camera window will show up (see attached picture: eupg_02.png)
11. Leave that window alone.
12. Open Papywizard (I used version 2.1.6-1).
13. Choose the "Preference" option from "Hardware" menu (see attached picture: eupg_03.png)
14. Select "Plugins" tab. Select "EOS Utility" from the "Shutter" drop down. (see attached picture: eupg_04.png)
15. In the "EOS Utility Shutter" window, make sure you have the correct path for the "EOS Bracket path" and set other options for exposure bracketing on this tab. (see attached picture: eupg_05.png)
16. Choose "Bulb" tab for bulb exposure settings. (see attached picture: eupg_06.png)
17. Choose "Focus" tab for focus bracketing settings. (see attached picture: eupg_07.png) Note using this plugin you can combine both focus and exposure bracketing same time.
18. Now connect the head by choosing "Hardware" menu and "Connect" option. (see attached picture: eupg_08.png)
19. Choose the number of images you want to take for the Mosaic or 360 pano.
20. Press "Shoot" button.
21. Press "Start" button.
22. For each position, Papywizard will be calling the EOSBracket.exe (keyboard macro) which in turn sends command to EOS Utility software.

I am attaching here an example that worked just before writing this user guide. See attached picture eupg_09.png. The first row shows the pictures taken at position 1. The second row shows the pictures taken at position 2. Within these two rows, the normal exposure, under exposure, over exposure and fused exposure are shown. The third row shows the resultant mosaic from the fused images.

These steps should work fine.

Jones





















no avatar
tarnis
Member
 
Posts: 179
Likes: 0 post
Liked in: 0 post
Joined: Wed Feb 18, 2009 8:54 pm
Location: Orlando, FL, US
Info

by tarnis » Fri May 08, 2009 12:38 pm

Can Eos Utility be run through WINE? Have issues in Windows with Papywizard, but this could eliminate the skipped picture problem I'm also having in linux :)

no avatar
AerialVr
Member
 
Posts: 45
Likes: 0 post
Liked in: 0 post
Joined: Thu Jan 15, 2009 5:53 pm
Location: Swansea,Ma
Info

by AerialVr » Fri May 08, 2009 12:55 pm

hi Jones,

I am connecting to both the camera and the mount with a wifi device server http://www.silexamerica.com/products-aamp-services-headermenu-28/31 and a usb hub. i don't have the release cable from the mount connected. do you think i have to have a wired connection from the laptop for this to work? I would like to put this on a 50 foot pole. when i get home tonight i will go thru your tutorial and see if i missed something.

Thanks
Chris

User avatar
fma38
Moderator
 
Posts: 5850
Likes: 2 posts
Liked in: 2 posts
Joined: Wed Dec 07, 2005 6:21 pm
Location: Grenoble, France
Info

by fma38 » Fri May 08, 2009 1:06 pm

tarnis, AFAIK, wine does not support usb...

AerialVr, I don't understand you question; if you are connected to the camera through the usb server, so you need to use a tethered shooting program (EOS Utility, Breeze...). If the wifi connection works, so, no, you don't need any cable.
Frédéric

User avatar
Castillonis
Member
 
Posts: 264
Likes: 0 post
Liked in: 0 post
Joined: Thu Mar 06, 2008 8:49 pm
Location: Oakland, Ca
Info

by Castillonis » Sat May 09, 2009 8:04 am

sjhenry, thanks for posting the concise directions along with the screenshots. I appreciate it. I purchased a Merlin and I am reviewing different netbooks. I am glad that you mentioned the minimum screen resolution of 1024 x 768 for the Canon utility to install / or work. I have noticed that almost all of the netbooks have a screen resolution of 1024 x 600 and that some of the netbooks with 1024 x 768 or 800 have glossy screens. Which netbook are you using?

User avatar
claudevh
Moderator
 
Posts: 1349
Likes: 0 post
Liked in: 0 post
Joined: Sun Nov 25, 2007 11:12 pm
Location: Mont-Saint-André (Belgium)
Info

by claudevh » Sat May 09, 2009 11:55 am

Hi Castillonis,

You can buy a Netbook with 1024 x 600 and use a small program like :

EEEctl for EEE pc http://cpp.in/dev/eeectl/
or
A1ctl for Acer Aspire One http://nodadev.wordpress.com/pc-projects/a1ctl/
I use this last one for my Acer ... and this work perfectly with my Canon softwares !

Those programs allow higher resolution for Netbook PC's

:cool:
:cool: Claude :cool:
Merlin + Papywizard on Windows 7 & Nokia 770 § N810 & Acer (Netbook) + PanoramaApp Androïd + Deltawave PapyMerlin BT + Autopano
Spherical Pano (180 x 360) with Canon 40D + Canon EF-S 10-22mm f/3.5-4.5 Zoom & Pôle Pano with Canon 5D MK2 and shaved Tokina 10-17 3.5-4.5 AF DX Fisheye
Gigapixel photography with Nikon D200 + Sigma 70-200 F 2.8 EX DG APO HSM

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Sat May 09, 2009 5:36 pm

Hi Castillonis,
I use an ASUS eeePC 901 model. It uses 2 SSDs - 4 gb C: drive and 8 gb D: drive. I install all my programs in D: drive only. I bought the SSD version so that I can take to mountains or more than 10,000 feet.

It uses 1 gb RAM which can be updated to 2 GB RAM easily. I have not upgraded to 2 gb yet.

The maximum screen resolution is 1024 X 600. But the video cord maximum resolution is 1024 X 768 which is fine for running the Canon EOS Utility. You have to switch over to 1024 X 768 by using the included software EeePC Tray Utility. The inconvenience is that you have to scroll the screen by placing the mouse at the right-top or right-bottom. You will not be able to see the full screen within the physical screen. If it is fine for you, then you can go with any model netbook. If you want to see the entire screen that supported by the physical screen size, then you have to choose the correct netbook.

I am attaching here two screen shots showing both resolution. The ss1.png is for 1024 X 600 and ss2.png is for 1024 X 768.

Jones





no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Sat May 09, 2009 5:42 pm

One more thing I forgot to mention. If you feel SSD has very small size, you can upgrade the second SSD to a bigger size. They are available at http://www.mydigitaldiscount.com/CategoryProductList.jsp?cat=Browse+By+Brand%3AMyDigitalSSD%3AMyDigitalSSD+PCI+Express+PCI-e+SSDs:Asus+EEE+PC+Mini+PCI-e+SSDs The EeePC forum is at http://forum.eeeuser.com/

Jones

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Sat May 09, 2009 5:51 pm

Hi Chris,

I have tested the EOS utility plugin only through wired connection. I would suggest the following trouble shooting procedure.

1. Connect your DSLR to your wireless server. Start the EOS utility from the laptop. Now try to take couple of photos with it. If it is working then EOS Utility is able to work the camera.

2. After the first step works fine, now you copy the bracket.ini file in the same directory where you keep the EOSBracket.exe. Set the values correctly in the .ini file. Run the EOSBracket.exe. It should send key board messages to EOS Utility and should take pictures.

You want to make sure the above two steps are working fine.

Jones

no avatar
AerialVr
Member
 
Posts: 45
Likes: 0 post
Liked in: 0 post
Joined: Thu Jan 15, 2009 5:53 pm
Location: Swansea,Ma
Info

by AerialVr » Mon May 11, 2009 9:19 pm

hi Henry,

fooled with it this weekend a bit. i didn't have my panohead so i ran papy wizard in sim mode. I think the problem occurs when the ev range is too high. I would do 5 shots at 1 step each but if i put 1 2/3 steps it would not complete the sequence at each position. It even started shooting a sequence of shots at the same exposure. i made my bracket.ini file with a text editor by cutting and pasting the code you gave and renaming it to .ini is this correct? or is there one i should copy and edit in the eos utility folder? it seems that if the number of shots and the steps per shot makes the camera go into bulb mode the whole process detrails. i don't think the wireless setup is the problem as it will work in the range is narrow enough. my camera is the 450d rebel xsi. hope this info will help someone else.

Chris

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Tue May 12, 2009 6:29 am

Chris,

I think what you are seeing is the boundary condition problem. I use Rebel XSI as well. The shutter speed range is 30 secs to 1/4000 secs. It sounds like when you change to 1 2/3 steps, it goes beyond 30 secs that is ending up in the BULB mode. The current keyboard macro works only when your 5 shots or any number of shots has the shutter speed within the range 30 secs and 1/4000 secs. If it exceeds either of the boundaries, it will not work.

In order to fix this problem, the key board script needs to be changed with 3 more additional information like maximum shutter speed (30 secs), minimum shutter speed (1/4000 secs) and base shutter speed (like 1/15 secs) for the normal exposure. Then the script can check for the boundary condition for the shutter speed. If it is more than 30 secs then turn to BULB mode and if it is less than 1/4000 secs then give an error message etc.

Jones

no avatar
AerialVr
Member
 
Posts: 45
Likes: 0 post
Liked in: 0 post
Joined: Thu Jan 15, 2009 5:53 pm
Location: Swansea,Ma
Info

by AerialVr » Wed May 13, 2009 2:27 pm

hi John,

did you also try a wider range and get the same result? Is it that much harder to do a script for dslr remote. that will shoot whatever range i need with no hicupps?

Thanks
Chris

no avatar
jeremyp
Member
 
Posts: 33
Likes: 0 post
Liked in: 0 post
Joined: Sun Feb 15, 2009 4:28 am
Location: Sydney, Australia
Info

by jeremyp » Thu May 14, 2009 12:27 am

Hi sjhenry,

Do you have any details on capture speed? I have done a few tests using gphoto with the 20D and it waits for each photo to be downloaded to the memory card before taking the next (i.e. does not take advantage of the buffer). I've had problems with this in the past using the Canon SDK directly so am interested to see how fast your technique is.

I'm capturing around 7 images per direction to capture the scenes full dynamic range - so the faster the better.

Cheers,
J

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Thu May 14, 2009 4:24 pm

Hi Chris,

Yes. Once I reach the shutter time value more than 30 sec, I will end up in the bulb mode. In EOS Utility you have to press space bar to open the shutter in the bulb mode, wait for the exposure time and press the space bar again to close the shutter. The current keyboard macro works only within the 30 secs and 1/4000 secs boundary.

The bulb mode on the second tab of the plugin will allow the base or normal exposure of 1 secs and above. If you use that one, then you should be able to go more than 30 secs.

When I find some time, I will try to re-write the keyboard macro so that it takes care of this boundary issue. As I mentioned in my earlier post, I have to add three more parameters to do that.

I'll also look at the DSLR Remote Pro and see what the options are possible.

Jones

PS: The ideal solution is to use the EOS SDK and write a command line utility that is specific to Papywizard's need for exposure and focus bracketing.
Last edited by sjhenry on Thu May 14, 2009 4:33 pm, edited 1 time in total.

no avatar
sjhenry
Member
 
Topic author
Posts: 146
Likes: 0 post
Liked in: 0 post
Joined: Tue Mar 10, 2009 1:43 am
Location: Colorado, USA
Info

by sjhenry » Thu May 14, 2009 4:31 pm

Hi Jeremy,

The printer example I attached here which has 3 exposures took about 27 secs for 2 position 3 exposures if I remember correctly. The EOS Utility gives the option of storing the picture in the memory card or download to laptop/netbook. I always use it to download to the computer. The script waits for 1 sec after pressing the shutter speed. If the camera is able to transfer it faster, it should be able to do it faster. If it is slower, then you can store it in the camera itself.

Jones

Next

Who is online

Users browsing this forum: No registered users and 2 guests